5ちゃんねる ★スマホ版★ ■掲示板に戻る■ 全部 1- 最新50  

■ このスレッドは過去ログ倉庫に格納されています

第1回昔のPC板杯プログラムコンテスト

1 :あまぐらまぁ:01/12/20 20:21
毎年恒例となった 第1回昔のPC板杯プログラムコンテストを開催するヨ!
かつてやった(であろう)クダラネー!!プログラムや クダラネー!!テクニックを
再びここで披露して下さい。

目的:画面上に100回「オマエモナー」と表示させる。
   特例としてカナが使えない機種は「OMAEMONA-」でも良い。
使用機種:不問
使用言語:BASIC限定(各機種の方言の使用は可)
条件:プログラムコードが長くならないように注意。
   (省略されました・・全てを読むにはここを押してください)が
   出てしまったら、そのエントリーは無効。
評価:綺麗なソースやアルゴリズムだけではなく、実行したときの芸術性
   なども評価の対象とする。
   表示1回毎に色を変えたり音を出したり等、演出を凝らすのは
   構わない。各自工夫してプログラムすること。
   ネタ歓迎!。

エントリーする人は、動作機種を(ものによっては何BASICかも)明記してくれ。
エントリーに対するレスなんかも大いにしちゃって!。もりageて行こう!
ビクーリするようなヤツ期待してます!

2 :あまぐらまぁ:01/12/20 20:22
使用機種:PC-8801 (N88-BASICトカ)

100 CLS:CONSOLE 0,25,0,1
110 CNT=0
120 COLOR (CNT MOD 7)+1
130 PRINT "オマエモナー ";
140 CNT=CNT+1
150 IF CNT<100 THEN GOTO 120
160 END

まずはオーソドックスに。

3 :大学生MSXユーザ:01/12/20 21:16
使用機種:MSX(多分全機種OK)
タイトル:BASICで自己書き換え

10 DATA "0023800A00A0200F1C3A822049EF1220"
20 DATA "D9200F643A9122B5CFB4D3C52D20223B"
30 DATA "3A83000000"
40 AD=32767:FORI=1TO3:READ A$
50 FOR J=1 TO LEN(A$)/2
60 POKE AD+J,VAL("&H"+MID$(A$,J*2-1,2))
70 NEXT:AD=AD+16:NEXT:RUN

4 :ナイコンさん:01/12/20 22:37
>>2-3
涙が出るほど懐かしい〜

5 :名梨産@MSX:01/12/20 23:38
MSXで作った1行スキーゲームです。9年前の自信作。
ParaMSXというエミュで動作確認できました。
http://my.dreamwiz.com/sharksym/

1 SCREEN0:WIDTH40:KEYOFF:COLOR2,0:CLEAR:
DEFINTA-Z:X=219:FORA=0TO1STEP0:LOCATERND
(1)*37,25:PRINT"AAA":X=X+(STICK(0)=3)*(X
<238)-(STICK(0)=7)*(X>200):IFVPEEK(X)=32
THENVPOKE(X),88:P=P+1:NEXTELSEPRINTP;"po
ints."

6 :ナイコンさん:01/12/20 23:43
使用機種:PC-6001mkII(N60m-BASIC)

10 CLS
20 FOR I = 1 TO 100
30 ? "オマエモナー"
40 TALK "F2 OMAEMONA-."
50 NEXT I
60 END

しゃべらせてみました。

7 :ナイコンさん:01/12/21 00:07
>>1
毎年恒例第1回ってのにワラタよ

8 :名梨産@80:01/12/21 00:10
うがぁ!目的が限定されていたのかぁ!
すいません。。エントリー取り消してください。。。(恥

9 :名梨産@5:01/12/21 00:18
しかも@80じゃなくて@5だし(鬱
大人しく他の人のソース見ますです。。。。

>>6
確か男の声と女の声を切り替えられませんでしたっけ?

10 :旧機種に優しい。ともちん:01/12/21 00:28
>>2の50行をみて、こんなやりかたあるんだぁ。と思ったのは私だけかな?

11 :ナイコンさん:01/12/21 00:33
あぁぁ。涙が出るほど懐かしいよ〜!

12 :ナイコンさん:01/12/21 00:48
10 SCREEN0:WIDTH40:KEYOFF:COLOR4,1,1:FORI=0TO1:PRINT"BABEL ";:I=0:NEXT

13 :名梨産:01/12/21 00:59
度々すいません。リベンジします。
ParaMSXはJIS文字が使えないので動作確認は
できませんが、動くと思います。

1 SCREEN0:WIDTH40:KEYOFF:COLOR2,0:CLEAR:
DEFINTA-Z:X=219:B=1:FORA=0TO1STEP0:LOCAT
ERND(1)*37,25:PRINTMID$("モナーオマエ",(B+1)/2
*3+1,3):X=X+(STICK(0)=3)*(X<238)-(STICK(
0)=7)*(X>200):IFVPEEK(X)=32THENVPOKE(X),
88:P=P+1:NEXTELSEPRINTP;"points."

>>12
パトレイバーでしたっけ?(藁

14 :ナイコンさん:01/12/21 12:24
>>6
100回ループするのが先か、STOPキーを押してしまうのが先か・・・。
忍耐力を要求されるな。

15 :ナイコンさん:01/12/21 13:02
PC-98(N88BASIC)ちょっとひねってみた
10 CLS 3
20 FOR I=0 TO 99
30 PRINT CHR$(&HB5)+CHR$(&HCF)+CHR$(&HB4)+CHR$(&HD3)+CHR$(&HC5)+CHR$(&H2D)+CHR$(&H13)
40 NEXT

16 :ナイコンさん:01/12/21 13:13
10 ?"オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー "
20 ?"オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー "
30 ?"オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー "
40 ?"オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー "
50 ?"オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー "
60 ?"オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー "
70 ?"オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー "
80 ?"オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー "
90 ?"オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー "
100 ?"オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー "
110 ?"オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー "
120 ?"オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー "
130 ?"オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー "
140 ?"オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー "
150 ?"オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー "
160 ?"オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー "
170 ?"オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー "
180 ?"オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー "
190 ?"オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー "
200 ?"オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー "

17 :ナイコンさん:01/12/21 13:16
>>16
力技ですなァ

18 :ナイコンさん:01/12/21 15:11
10 CLS:WIDTH 80,25
20 X=20:Y=12
30 FOR I=1 TO 100
40 LOCATE X,Y : PRINT "オマエモナー";
50 A$=INKEY$ : IF A$="" THEN 50
60 LOCATE X,Y : PRINT "   ";
70 X=X+(A$="4")-(A$="6")
80 Y=Y-(A$="2")-(A$="8")
90 NEXT

手抜きしてるから端にいくとエラーで止まる

19 :ナイコンさん:01/12/21 15:14
見りゃわかる人が多いと思いますが、
使用機種&使用したBASICも書いてください。

20 :18:01/12/21 15:19
スマソ
N88BASICです。

21 :JOY:01/12/21 15:27
実は >>1だったりもします。
>>18
INKEY$なんて何年か振りに見たヨ!。ありがとう!

22 :ナイコンさん:01/12/21 15:48
厨房に戻ったつもりで「インキンだりぃ〜!」<絶叫

>>16 激しくワラタ

23 :大学生MSXユーザ:01/12/21 18:55
仕様機種:MSX(全機種)

10 SCREEN0:WIDTH40:CLS:PRINT"オマエモナー"
20 LOCATE0,20:FORI=0TO799:COLORIMOD16
30 VPOKEI,VPEEK(IMOD8):NEXT

24 :大学生MSXユーザ:01/12/21 18:56
>>23
訂正
仕様機種:〜→使用機種:〜

25 :ナイコンさん:01/12/21 19:02
>>16に敬意を表して

110 REM オマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナー
120 REM オマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナー
130 REM オマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナー
140 REM オマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナー
150 REM オマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナー
160 REM オマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナー
170 REM オマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナー
180 REM オマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナー
190 REM オマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナー
200 REM オマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナーオマエモナー
210 LIST

26 :ナイコンさん:01/12/21 22:42
FM-7他(F-BASIC)

10 CLS
20 I=0
30 FOR Y=0 TO 19:FOR X=0 TO 4
40 XX=X*128+((I MOD 2)*96)
50 YY=Y*10+((I MOD 2)*7)
60 SYMBOL(XX,YY),"オマエモナー",2,1,I MOD 7+1,(I MOD 2)*2
70 I=I+1
80 NEXT:NEXT
90 A$=INPUT$(1)
100 END

27 :JOY ◆chesX68k :01/12/21 23:02
>>25
表示してないジャン!!と思わせといて 210行のLIST文が泣かせます。

>>26
お、SYMBOLとは考えましたね!!。懐かスィーよ!!
表示もカラフルで良い感じ〜。スバラシイ!!

28 :ナイコンさん:01/12/22 00:15
10 PRINT "コノ プログラムハ 10ビョウゴ ニ ショウメツスル"
20 FOR I=0 TO 10000:NEXT
30 NEW

29 :ナイコンさん:01/12/22 02:28
大賞はこれに決定!!
http://pc.2ch.net/test/read.cgi/i4004/1008579489/27
ワラタ

30 :ナイコンさん:01/12/22 04:27
>>25がいいなぁ。こんなん普通思い付かないよ(^^;;

31 :HuBasic:01/12/22 05:15
10 CLS:N=0
20 IF 100<N THEN END
30 N=N+1:KEY0,CHR$(30,30)+"オマエモナー"+CHR$(29,29,29,29,29,29,31)+"GOTO20"+CHR$(13)

# じつはテストしてない

32 :MZ-1500:01/12/22 11:07
10 CLS
20 FOR I=1 TO 100
20 CO=INT(RND(1)*7)+1
30 X=INT(RND(1)*26)
40 COLOR CO,0
50 LOCATE X,24:PRINT"オマエモナー"
60 NEXT I
70 END

テスト無し。
7色の「オマエモナー」が画面下の任意の位置に現れながら
スクロールアップしていくはず。

33 :名無しさん@R800:01/12/22 13:48
N88互換BASIC
www.vector.co.jp/soft/win95/prog/se055956.html

5 randomize:cls:color 3,0
10 x=rnd(1):y=int(x*255)
11 if y > 240 then 13
12 print"オマエモナー ";:h=0:goto 15
13 print"オレガナー ";:h=1
15 for i=0 to 255:for j=0 to 255:next j:if h=0 and inkey$="2" then 20 else if h=1 and inkey$="2" then 21:next i
18 if h=0 then 10
20 color 4:print"イッテヨシ!":end
21 color 7:print"マンセー!!":end

”オマエモナー”に混ざって”オマエガナー”が出て来ますので
タイミング良く「2」を押して下さい。(ザカリテゲーム)
難易度は適当にjのループ数を変更して下さい。(藁

34 :32:01/12/22 14:50
>>32 デバッグ
行番号20が2行ある。以下に書き直し。
25 CO=INT(RND(1)*7)+1
スマソ

35 :名無しさん@R800:01/12/22 14:56
>>33
このN88BASICはマシン個体差を吸収してないかもしれないので、
jの空ループを更に5回程ループさせた方が良いかもしれません。
皆さん適当に改造して遊んでください。

36 :ナイコンさん:01/12/22 15:19
N-88BASIC(86)

1 cls:cl=0
7 for b=1 to 100
15 restore
87 for a=1 to 7
150 color cl
476 cl=(cl+1) and 7
1327 print a$;
6594 next
13258 next
65201 data オ,マ,エ,モ,ナ,ー," " 

37 :36:01/12/22 15:22
しまった!色番号0対策忘れた・・・・鬱。

38 :スマソ、修正。:01/12/22 15:27
1 cls:cl=0
7 for b=1 to 100
15 restore
87 for a=1 to 7
150 color cl
476 cl=(cl+1) and 7
698 if cl=0 then cl=1
819 read a$
1327 print a$;
6594 next
13258 next
65201 data オ,マ,エ,モ,ナ,ー," "

39 : :01/12/22 15:38
>>38
行番号の付け方がステキ!

40 :JOY ◆chesX68k :01/12/22 17:19
>>23
正直MSXを使ったことがないので、VDPいじられると動作が読めないっすわ スマソ。
きっと面白い効果になるんだろうなぁ。
ちゃんと空ループ入れてるのもポイント高し。

>>31
キーバッファに放り込んで自動実行させるタイプですな。HuBASIC系独特の。
で、これは本当に動く?

41 :名無しさん@R800:01/12/22 17:20
N88互換BASIC

5 randomize:cls:color 7
6 for i=0 to 7:h(i)=23:next i
7 for y=0 to 23:locate 15,y:print"|";:for i=0 to 47:print " ";:next i:print"|":next y
10 for i=0 to 99:c=i mod 8:color c
20 m=int(rnd(1)*8):n=m*6:x=16+n:locate x,0:print"オマエモナー"
30 for y=1 to h(m):locate x,y:print"オマエモナー":locate x,y-1:print" ":next y
40 h(m)=h(m)-1:next i
50 color 7:for i=0 to 6:b$(i)="":for j=0 to 11:read a:b$(i)=b$(i)+chr$(a):next j:next i
60 for y=17 to 8 step -1
70 for i=0 to 6:locate 34,y+i:print b$(i):next i
80 next y:end
100 data 32,32,32,32,32,124,32,32,32,32,32,32
110 data 32,116,45,45,45,43,45,45,45,116,32,32
120 data 32,32,32,45,45,45,45,45,32,32,32,32
130 data 32,32,45,45,43,45,43,45,45,32,32,32
140 data 32,32,32,47,32,32,124,32,32,32,32,32
150 data 32,32,47,32,32,32,32,76,95,95,32,32
160 data 32,32,32,32,32,32,32,32,32,32,32,32

もうちょっと凝ってみたい気もするが、とりあえず。

42 : ◆MZ80K.vA :01/12/22 17:26
>>25
感動した。
欲を言えば、最終行はこれなかどう?

210 LIST 110-200

43 :ナイコンさん:01/12/22 17:26
SHARP BASIC SP-50X0の場合。

LIST
10 PRINT"C":J=53248:FORI=1TO100
20 POKEJ,166:J=J+1:POKEJ,138:J=J+1:POKEJ,165:J=J+1:POKEJ,141:J=J+1
30 POKEJ,149:J=J+1:POKEJ,191:J=J+1:POKEJ,207:J=J+1:NEXT
READY
DATA ERROR
READY


10行の「C」はリバース文字。(画面消去文字)
1行80カラムの制限がある。
実行すると、画面の左上から、「オマエモナー」と顔キャラクタを100回表示する。
各文字は、ASCIIコードとは別系統の「ディスプレイコード」。
「DATA ERROR」の表示は、直前の「READY」でCRキーを押した時に出るお約束。
 MicrosoftBASICで言うところの「Out Of Data」。

44 :名無しさん@R800:01/12/22 17:33
>>41
30行目の後ろのprint文はスペース6個です。失礼しました。

45 :ナイコンさん:01/12/22 17:37
スペースは全角て

46 :ナイコンさん:01/12/22 18:50
5 DIM A$(99):gosub *read
10 A=int(rnd*15)
20 B=int(rnd*15)
30 C=3+int(rnd*15)
40 if int((A-1)/3)=(A-1)/3 then 50 else 10
50 if int((B-2)/3)=(B-2)/3 then 60 else 20
60 if int(C/3)=C/3 then 120 else 30
120 print A$(A);A$(B);A$(C)
130 goto 10
150 *read
160 I=1
170 read A$(I)
180 if A$(I)="逝ってよし" then return
190 I=I+1
200 goto 170
210 DATA ネオ麦茶が,九州で,西鉄バスを乗っ取った,ラディンが,ニューヨークで,ビルを破壊した
220 DATAオウムが,地下鉄日比谷線で,サリンをぶちまいた,キャットキラーが,一人で暴言はにゃ〜んスレッドで,1000をとれなかった
230 DATA 埼玉の学生が,WinMXで,逮捕された,ひろゆきが,自宅で,警察に押し掛けられる,逝ってよし

47 :ナイコンさん:01/12/22 18:55
5 data a,b,c,d,e,f,g,h,i,j,k,l,m,n,o,p,q,r,s,t,u,v,w,x,y,z,
10 cls 3:color 7:width 100,30
20 dim a$(25):dim k(80):i=0:ii=0:s=80:ki=1
30 for a=1 to 26
40 read a$(i):I=i+1
50 next a
100 for k=0 to s
110 r=rnd*27
115 if r=>25 then goto 110 else goto 116
116 'print r
120 k(ii)=r:ii=ii+1
130 next k
140 for j=1 to s
150 locate j-1,y:color 4:print a$(k(j));
160 next j
200 'key
210 ke$=inkey$:if ki>80 then i=1:ki=1:ii=0:y=y+2:goto 100
220 if ke$="" then 210
230 if ke$=a$(k(ki)) then locate ki-1,y+1:color 5:print a$(k(ki));:ki=ki+1:beep:goto 210:else locate ki-1,y+1: color 2:print ke$:color 7:beep:goto 210
215 line (ki*8-8,y*16)-(ki*8,y*16+32),6,b

48 :47:01/12/22 19:01
width 100,30は80,25の間違い・・無くてもよし。

49 :大学生MSXユーザ@(3 AND 23):01/12/22 19:36
>>40

>>23の動作解説してみます。
SCREEN0だと、VRAMの0番地からが画面に表示している
文字の文字コードが入ってます。
で、VRAMの0番地からに対応する個所に「オマエモナー」と書いて(10行)、
残りの「オマエモナー」はループまわして(20行)最初に書いた所から
文字コードを拾ってきてコピペ(30行)します。
そのときに文字色をいじることで(20行)ちょっと表示を派手にしてます。

>>3の解説いりますか?

とまぁ、解説だけではアレなんでもう1個。

動作機種:MSX(多分全機種(動作未確認))

10 'A ーナモエマオ A
20 FORAD=32768TO32800:IFPEEK(AD)=65THEN30ELSENEXT
30 TP=AD+1:FORAD=TPTO32800:IFPEEK(AD)=65THEN40ELSENEXT
40 ED=AD-1:FORI=1TO100:FORAD=EDTOTPSTEP-1
50 PRINT CHR$(PEEK(AD));NEXT:NEXT

50 :大学生MSXユーザ@(3 AND 23):01/12/22 19:37
>>49
ぐはぁ、誤植ハケーン

50行は↓こうです。
50 PRINT CHR$(PEEK(AD));:NEXT:NEXT

51 :25:01/12/22 21:42
>>42
ああ、やっぱりそれで良かったですか。
LISTの文法がうろ覚えだったので、"LIST"だけにしておきました。

ところで、N60-BASICでは、プログラム中に"LIST"があると、
後に何があろうと、リストを表示した時点でプログラムが終わってしまったんですが
他のマシンでもそうだったんでしょうか?

52 :ナイコンさん:01/12/22 22:41
オーソドックスなBASICプログラム。

10 LET A = 0
20 LET A = A + 1
30 IF A = 100 THEN GOTO 100
40 PRINT "OMAEMONA- ";
50 GO TO 20
100 STOP
110 END

53 :ナイコンさん:01/12/22 22:45
>>51

Hu-BASIC系は、

10 LIST:RUN

が正常に実行できたと思う。

54 :ナイコンさん:01/12/22 23:07
>>53
X1ではダメだったような記憶がありますが、
間違ってるかも。。。

55 :25:01/12/22 23:25
ちょっと脱線したのでネタ振った責任をとってひとつ

PC-6001 N60-BASIC

10 REM *** ジンコウムノウ オマエモナー ***
20 CLS
30 FOR I=1 TO 100
40 INPUT A$
60 PRINT ">>";A$
70 PRINT "オマエモナー"
80 NEXT

56 :ナイコンさん:01/12/23 00:20
>>55にワラタ
勝手に改造

PC-6001 N60-BASIC

10 REM *** ジンコウムノウ オマエモナー ジドウ ジザクジエン***
20 CLS
30 FOR I=1 TO 100
40 INPUT A$
50 PRINT I*2-1;"ナマエ:ナイコンサン トウコウビ:";DATE$;" ";LEFT$(TIME$,5)
51 PRINT "    ";A$
55 PRINT I*2;"ナマエ:ナイコンサン トウコウビ:";DATE$;" ";LEFT$(TIME$,5)
60 PRINT "    >>";A$
70 PRINT "    オマエモナー"
80 NEXT

57 :ナイコンさん:01/12/23 00:38
>>56
いいアイデアだけど
N60−BASICにはDATE$、TIME$はないよ。

どっちっかつーっと、N−BASICかな?

58 :56:01/12/23 00:51
あららしまった。
うちのはN88でした・・・

59 :ナイコンさん:01/12/23 02:04
高校生の頃、こんな感じのプログラムを作ったことがある。
で、DISK-BASICで自動起動

PC-9801 N88-BASIC

10 WIDTH 80,25:CLS
20 F=0:A$="■":X=0:Y=3:C=0
30 PRINT "NFC OMAEMONA-BASIC"
40 PRINT "Copyright(C) Micro$oft云々"
50 PRINT "Ok"
60 LOCATE X,Y:PRINT A$;
70 F = F + 1
80 IF F = 100 AND A$ = "■" THEN A$=" ":F=0
90 IF F = 100 AND A$ = " " THEN A$="■":F=0
100 B$=INKEY$
110 IF B$="" GOTO 60
120 IF ASC(B$) > 31 THEN LOCATE X,Y:PRINT B$;:X=X+1:IF X>79 THEN X=0:Y=Y+1
130 IF ASC(B$) = 13 THEN 150
140 GOTO 60
150 LOCATE X,Y:PRINT " ":PRINT "?オマエモナー Error":PRINT "Ok":C=C+1
160 IF C = 100 THEN END
170 X=0:Y=Y+3
180 IF Y > 23 THEN Y=23:PRINT
190 GOTO 60

記憶を頼りに適当に書いたので、バグ在中かも。特にスクロール関連。
80-90行のFの判定は、カーソルの点滅のタイミングに合わせて適当に変更。

60 :59:01/12/23 02:10
>>559
120行でYが増えたあとYのチェックをしてないじゃん。

120 IF ASC(B$) > 31 THEN LOCATE X,Y:PRINT B$;:X=X+1:IF X>79 THEN X=0:Y=Y+1:IF Y > 23 THEN Y=23:PRINT

61 :59:01/12/23 02:11
559→59だし・・・鬱

62 :旧機種に優しい。ともちん:01/12/23 02:27
>>54
今、X1エミュ+Hu-Basic1.0で試したら通ったYO!

63 :59:01/12/23 02:43
すまない。
>>33のN88互換BASICで試してみたら、バグがあったのでさらに修正

120 IF ASC(B$) > 31 THEN LOCATE X,Y:PRINT B$:X=X+1:IF X > 79 THEN X=0:Y=Y+1:IF Y>23 THEN Y=23:PRINT;

64 :ナイコンさん:01/12/24 01:20

PC-9801 N88-BASIC

100 WIDTH 80,25:CLS
110 X=70
120 FOR I=1 TO 100
130 FOR J=1 TO 7
140 B=X+J
150 IF B > 79 THEN B=B-79
160 Y = 12 - SIN(B*10*3.14/180)*10
170 LOCATE B,Y:PRINT MID$("オマエモナー ",J,1);
180 NEXT
190 X=X-1:IF X < 0 THEN X=79
200 FOR J=0 TO 50:NEXT
210 NEXT

サインカーブを描いて"オマエモナー"が移動します。

65 :環境(config,sys?)に優しい。ともちん:01/12/24 01:24
>>64
速すぎるので、適当なウェイトを入れたほうがいいかも?

66 :ナイコンさん:01/12/24 16:14
こうしてみると、不思議とN88派が多いな。

67 :ナイコンさん:01/12/24 18:46
>>66
9801を通ってきてる人は多いからね。
N60でやりたいんだけど検証環境がない。

68 :ナイコンさん:01/12/24 18:58
無料のN88互換BASIC for windows
テキストファイルにコピペするだけで動くから楽だYO!

http://www2s.biglobe.ne.jp/~yamadai/

69 :ナイコンさん:01/12/24 19:00
>>68
よくマイクロソフトに訴えらんねーな(w

70 :ナイコンさん:01/12/24 19:16
>>69
別にソース丸写しじゃなきゃ問題ないでしょ?
ただの移植プログラムなんだし

71 :ナイコンさん:01/12/24 19:24
>>70
コードの一部分やロジックも全く流用していれば問題ないと思われ。
で流用してないの?

72 :ナイコンさん:01/12/24 19:27
>>69
言語に著作権があると思ってる人ハケーン

73 :ナイコンさん:01/12/24 19:27
ロジックも流用していれば→ロジックを流用していなければ

74 :ナイコンさん:01/12/24 19:29
>>72
厨房を発見しました!
これより迎撃体制に入ります。

75 :ナイコンさん:01/12/24 19:36
>>69-74
別スレでやってちょうだい。

76 :ナイコンさん:01/12/24 19:38
>>75
オマエモナ

77 :ナイコンさん:01/12/25 00:31
>>56をさらに勝手に改造

N88-BASIC
10 REM *** ジンコウムノウ オマエモナー ジドウ ジザクジエン v1.1 ***
20 CLS
30 DIM A$(5)
40 C=0
50 FOR I=1 TO 5
60 READ A$(I)
70 NEXT
80 INPUT B$
90 PRINT 1;" ナマエ:ナイコンサン トウコウビ:";DATE$;" ";LEFT$(TIME$,5)
100 PRINT "    ";B$
110 FOR I=2 TO 1000
120 R=INT(RND(1)*5)+1:IF 1001-I=100-C THEN R=1
130 IF C=100 THEN R=INT(RND(1)*4)+2
140 PRINT I;" ナマエ:ナイコンサン トウコウビ:";DATE$;" ";LEFT$(TIME$,5)
150 PRINT " >>";I-1
160 PRINT "    ";A$(R)
170 IF R=1 THEN C=C+1
180 NEXT
190 PRINT " 1001 ナマエ:1001 トウコウビ:Over 1000 Thread"
200 PRINT "    コノスレッドハ1000ヲコエマシタ"
210 PRINT " モウカケナイノデ アタラシイスレッドヲタテテクダサイ"
220 END
230 DATA "オマエモナー","イッテヨシ","ハァハァ","ハゲシクドウイ","ワラタ"

ちゃんと"オマエモナー"は100回表示されるはず。

78 :ナイコンさん:01/12/25 00:52
>>25
思わず吹き出してツバをモニタに飛ばした(藁
続いて26から見ます

79 :大学生MSXユーザ@(3 AND 23):01/12/25 01:47
使用機種:MSX(多分何処の国のマシンでもOK)

10 DATA "00043e0c14142400"
20 DATA "00f71212a2422f00"
30 DATA "007c117c10108d00"
40 DATA "0040e0405c800000"
50 SCREEN1:WIDTH32:CLS
60 FORI=0TO99:PRINT"ABCD";:NEXT
70 TIME=0:FORI=0TO600:I=TIME:NEXT
80 FORC=65TO68:READA$:FORI=0TO7
90 N=VAL("&H"+MID$(A$,I*2+1,2))
99 VPOKE 8*C+I,N:NEXT:NEXT

80 :ナイコンさん:01/12/25 01:52
SP-5030のカーソル移動記号などはどう表記したものかな〜。

81 :ナイコンさん:01/12/25 21:06
お前モナーでキータッチ 半角全角ひらカタランダムです
N88互換BASIC 全機種OKだと思う。
10 data お,オ,オ,ま,マ,マ,え,エ,エ,も,モ,モ,な,ナ,ナ,ー,ー,-,お前モナー
20 I=0:dim A$(99):cls
30 read A$(I)
40 if A$(I)="お前モナー" then 60
50 I=I+1:goto 30
60 I=0:for K=1 to 6
70 R=int(rnd*5)
80 if R>2 then 70
90 Q$=Q$+A$(I+R)
100 I=I+3
110 next K
120 color 5:print Q$
130 line input Y$
140 if Y$=Q$ then color 4:print"(・∀・)イイ":Q$="":goto 60 else color 2:print "違うぞゴルァもう一回打て!":color 5:goto 130

82 :ナイコンさん:01/12/25 21:08
>>79
MSXはよく分からないけど、"ABCD"のフォントを書き換えて
"オマエモナー"を表示してるってことでいいのかな?

久しぶりに16進をドット絵変換したよ。

83 :ナイコンさん:01/12/25 21:53
>>81
昔ってことでカナ入力タイピングゲームもよかろう。

N88-BASIC

10 COLOR 7:CLS
20 A$="オマエモナー":B$="6j5mu-"
30 T$=TIME$:E=0:LOCATE 31,12:PRINT A$;
40 FOR I=1 TO 100
50 FOR J=1 TO 6
60 COLOR 2:LOCATE 30+J,12:PRINT MID$(A$,J,1);
70 C$=INKEY$
80 IF C$="" THEN 70
90 IF C$<>MID$(B$,J,1) THEN BEEP:E=E+1:GOTO 70
100 COLOR 7:LOCATE 30+J,12:PRINT MID$(A$,J,1);
110 NEXT
120 PRINT I
130 NEXT
140 PRINT "START ";T$
150 PRINT "END ";TIME$
160 PRINT "MISS ";E

CapsLockはオフの方向で。

84 :大学生MSXユーザ:01/12/25 22:38
>>82
そうです。

・・・なんか俺ばっかり書いてるような気がする。
鬱だ。

#MSX-BASIC、N88-BASIC以外のBASICのコードキボンヌ>oll

85 :JOY ◆chesX68k :01/12/26 03:54
しばらく留守にしてたけど、このスレ盛り上がってたんで安心したーヨ。
さすが2chらしい面白いアイディアの方向に発展してて、これからが
楽しみやねー。奇抜なのをボシュー!!。

>>84さんの言う通り、「読めネーヨ!!」級の機種依存バリバリなプログラム
見てみたいですわ。

っていうか、勝手に仕切ってるみたいでスマソ。

86 :X1F:01/12/26 09:01
X1用 Hu-BASCI (V1 or V2)
10 J=0:GOTO 1000
999 END
1000 CLS:FOR I=10 to 100 STEP 10:PRINT J+I;" PRINT ";CHR$(32);"オマエモナー";CHR$(32):NEXT
1010 J=J+1:if(J=10) then PRINT "RUN" else "GOTO 1000"
1020 KEY 0,STRING$(10,11)

動作確認していないので、動くかどうか不安ですが。

87 :86:01/12/26 09:40
>>86
1020行にバグ発見。正しくは、
1020 LOCATE 0,0:KEY 0,STRING$(10,11)
です。

88 :ナイコンさん:01/12/26 10:27
N60BASIC ("□"はスペース)他機種移植も容易だと思います。

1 CLS:S=0:T=0
2 FOR L=1 TO 5:LOCATE 0,L:PRINT L;":";:X(L)=20:NEXT L
3 LOCATE 0,0:INPUT "よそう□1-5";Y
4 FOR L=1 TO 100
5 R=INT(RND(1)*5)+1:X=X(R):IF X<=0 THEN 5
6 X=X-1:LOCATE X+2,R:PRINT "オマエモナー□";
7 IF X<=0 THEN S=S+1:PRINT S;"ちゃく";:IF S=1 THEN T=R
8 X(R)=X:FOR M=1 TO 1:NEXT M
9 NEXT L:LOCATE 0,7:PRINT "かち=";T;"□";
10 IF T=Y THEN PRINT "あたり!!大金もち!":GOTO 12
11 PRINT "はずれ!!大びんぼう!"
12 PRINT:INPUT "もういちど□やる?(Y/N)";Y$
13 IF Y$="Y" OR Y$="Y" THEN 1
14 END

89 :88:01/12/26 10:34
あう、88の13行にバグ発見(T_T)
13 IF Y$="Y" OR Y$="y" THEN 1
です。

90 :ナイコンさん:01/12/26 14:29
>>88
"大金"もち、"大"びんぼうにやられた。

91 :ナイコンさん:01/12/26 16:32
N88-BASIC(86)一応実機で確認済

10 screen 3,0:cls 3
20 for a=1 to 100
30 restore
40 for b=1 to 16
50 read x1,y1,x2,y2
60 line (x1,y1)-(x2,y2),7
70 next
80 roll 20
90 next
100 rem ---------------------------------------------
110 data 0,385,19,385, 10,380,10,399, 10,385,0,399
120 data 20,390,30,399, 20,380,38,380, 39,380,25,395
130 data 40,381,58,381, 50,381,50,399, 40,399,58,399
140 data 60,381,78,381, 60,390,78,390, 70,381,70,399, 70,399,78,399
150 data 80,385,99,385, 90,381,80,399
160 data 100,390,639,390

92 :ナイコンさん:01/12/26 16:43
WHILE 1:PRINT"テイコクバンザイ ";:WEND

93 :シトラス ◆TCUoE/5Q :01/12/26 17:28
>>33
そのN88互換BASICの作者ってσ(▼▼;)おれの高校の時の数学の先生だったんだよなぁ
いや、マヂで
東工大から富士通かどっかのプログラマやって教師になったらすぃ
エクセルのマクロで高校の図書館の蔵書管理システムつくってたなぁ
パソコンにバーコードリーダーつなげて…
大量の本にバーコード貼るの大変だったなぁ

94 :大学生MSXユーザ:01/12/26 19:33
新作です。
使用機種:MSX2以降

10 SCREEN 5:PSET(0,1):FORI=0TO1
20 READ A$:IF A$="アボーン"THEN 40
30 I=0:DRAW A$:NEXT
40 COPY (0,0)-(143,7) TO (36,0)
50 COPY(0,0)-(200,170)TO(0,9)
60 A$=INPUT$(1)
100 DATA "R4D3L2DLD2U2RUR2D3U7D"
110 DATA "R8D3L4UDRDRDRD"
120 DATA "R7L2U5L2R8"
130 DATA "L2U2L2R4L2D7R6"
140 DATA "URU2RU4D2L3R6"
150 DATA "DR5","アボーン"

95 :ナイコンさん:01/12/26 20:07
 か

96 :ナイコンさん:01/12/26 20:08
Abort
Ready

97 :イブニング256:01/12/26 23:13
10 'タイトル ブラクラ  タイオウキシュ N88BASIC,N88ゴカンBASIC
20 A=int(rnd*800)
30 B=int(rnd*600)
40 C=int(rnd*10)
50 AA=int(rnd*800)
60 BB=int(rnd*600)
70 if C>7 then 40
80 line(A,B)-(AA,BB),C,BF
90 for o=1 to 10
100 D=int(rnd*100)
110 E=int(rnd*30)
120 if D>80 or E>25 then 100
130 locate D,E:color C:print "オマエモナー":next o
140 goto 20

98 :MZ-1500:01/12/28 12:05
10 CLS
20 DIM C$(9)
30 FOR I=0 TO 16:READ C$(I):NEXT I
40 MN=0
50 CC=INT(RND(1)*7)+1:CR=INT(RND(1)*17)
60 COLOR CC,0:PRINT C$(CR);
70 IF CR=0 THEN MN=MN+1
80 IF MN<100 THEN 50
90 END
100 DATA "オマエモナー ","イッテヨシ ","マターリ ","サラシage ","(ワラ ","(・w・)V "
110 DATA ">>1サーン! ","ヤメレ ","ウプ キボンヌ ","アボーン ","(>ω<)Σガーン "
120 DATA "(・∀・)イイ ","ワショーイ ","(プ ","2チャンネラ ","DO-YO! ","サイコー "


:FOR I=1 TO 100:PRINT"オマエモナー";:NEXT I:END


1行プログラム

99 :MZ-1500:01/12/28 12:24
>>98
プログラムにバグは憑き物である。
プログラムを打ち込んだあと充実感に浸りながらRUN!ピー!ガックーン、ナヌー、オノレ!
この脱力感と怒りがたまらんのね。

20行目C$(9)→C$(16)でした。

以下は消し忘れでした(爆
1行プログラム
10 FOR I=1 TO 100:PRINT"オマエモナー";:NEXT I:END
スマソ

100 :100:01/12/29 00:15
100 GET A,G,E

101 :NPCさん:01/12/29 09:25
101 DELETE 100

102 :ナイコンさん:01/12/31 17:30
使用機種:Windows95/98/Me/NT4.0/2000/XP(たぶん)
条件:WindowsScriptingHost(IE4以降に同梱)が動く環境
注意:以下のテキストを拡張子.vbsで保存して実行してください

FOR I=1 TO 10
FOR J=1 TO 10
A=A+"オマエモナー"
NEXT
A=A+CHR(13)
NEXT
MSGBOX A,0,"オマエモナー"

103 :ナイコンさん:02/01/05 19:49
1000 PRINT"10 FOR I=1 TO 100
1010 PRINT"20 PRINT"オマエモナー ";
1020 PRINT"30 NEXT
1030 PRINT"RUN
1040 PRINT"オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー
1050 PRINT" オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー
1060 PRINT" オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー オマエモナ
1070 PRINT"ー オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー オマエモ
1080 PRINT"ナー オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー オマエ
1090 PRINT"モナー オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー オマエモナー ^C
1100 PRINT"Break in 20
1110 PRINT"Ok
1120 PRINT"■

104 :大学生MSXユーザ:02/01/08 19:47
あけおめです。

新年一発目です。比較的オーソドックスな作りにしてみました。
使用機種:MSX(多分MSX2未満はダメ)

3 A=RND(-TIME)*20+1:D=RND(-TIME)*1
5 FORI=1TO20:LOCATE2,Y(I):FORJ=1TO5
2 FORI=1TO20:Y(I)=I:NEXT:FORI=1TO100
1 SCREEN0:WIDTH40:COLOR2,0,0:DIMY(20)
7 COLORIMOD15+1:NEXT:LOCATE0,21:COLOR2
4 B=RND(-TIME)*20+1:SWAPY(A),Y(B):NEXT
6 W=ATN(.1)^ATN(1):PRINT"オマエモナー ";:NEXT

105 :HITBITでオマエモナー発声練習:02/01/08 21:21
初挑戦。SONY HITBIT(MSX)にて。
auto
10 CLS:COLOR 15,1,1:PLAY "T120"
20 FOR I=1 TO 25
30 PRINT "オマエモナー":PLAY "O3C16C8C16C4"
40 PRINT "オマエモナー":PLAY "E16E8E16E4"
50 PRINT "オマエモナー":PLAY "G16G8G16G4"
60 PRINT "オマエモナー":PLAY "O4C16C8C16C4"
70 NEXT I
80 END
どうでしょうか。

106 :105:02/01/08 21:47
クソプログラムですが手を加えました。(負荷によっては表示ズレます)
auto
10 CLS:COLOR 15,1,1:PLAY "T120"
20 FOR I=1 TO 25
30 PRINT "オ":PLAY "O3C16":PRINT "マエ":PLAY "C8":PRINT "モ":PLAY "C16":PRINT "ナー":PLAY "C4"
40 PRINT "オ":PLAY "E16":PRINT "マエ":PLAY "E8":PRINT "モ":PLAY "E16":PRINT "ナー":PLAY "E4"
50 PRINT "オ":PLAY "G16":PRINT "マエ":PLAY "G8":PRINT "モ":PLAY "G16":PRINT "ナー":PLAY "G4"
60 PRINT "オ":PLAY "O4C16":PRINT "マエ":PLAY "C8":PRINT "モ":PLAY "C16":PRINT "ナー":PLAY "C4"
70 NEXT I
80 END
どうでしょうか。

107 :FMV:02/01/08 22:06
Active basic N88互換
10 cls
20 x=int(rnd(1)*58):y=int(rnd(1)*20):i=i+1
30 locate x,y
40 print "オマエモナー"
50 if i<100 then goto 20

目的:画面上に100回「オマエモナー」と表示させる。
10 print "100回「オマエモナー」"
以上

108 :ナイコンさん:02/01/08 22:31
MZ-80 SP-5030 print文で複数出すのって;じゃなく,だったっけ?

10 READ A1$,A2$,A3$,A4$,A5$,B1$,B2$,B3$,B4$,B5$
20 READ C1$,C2$,C3$,C4$,C5$,D1$,D2$,D3$,D4$,D5$
30 READ E1$,E2$,E3$,E4$,E5$,F1$,F2$,F3$,F4$,F5$,CR$,UE$
40 FOR I=1 TO 100 : CURSOR INT(RND*9),INT(RND*19):
50 PRINT "C";A1$;CR$;A2$;CR$;A3$;CR$;A4$;CR$;A5$;UE$;
60 PRINT B1$;CR$;B2$;CR$;B3$;CR$;B4$;CR$;B4$;UE$;
70 PRINT C1$;CR$;C2$;CR$;C3$;CR$;C4$;CR$;C4$;UE$;
80 PRINT D1$;CR$;D2$;CR$;D3$;CR$;D4$;CR$;D4$;UE$;
90 PRINT E1$;CR$;E2$;CR$;E3$;CR$;E4$;CR$;E4$;UE$;
100 PRINT F1$;CR$;F2$;CR$;F3$;CR$;F4$:CR$;F4$:NEXT:END
110 DATA " @ ","@@@@@ "," @@ "," @ @ ","@ @ "
120 DATA "@@@@@ "," @ "," @ @ "," @ "," @ "
130 DATA "@@@@@ "," @ "," @ "," @ ","@@@@@ "
140 DATA "@@@@@ "," @ ","@@@@@ "," @ "," @@@ "
150 DATA " @ ","@@@@@ "," @ "," @ "," @ "
160 DATA " "," ","@@@@@ "," "," "
170 DATA "←←←←←←↓","↑↑↑↑↑"

109 :ナイコンさん:02/01/08 22:35
>>107
Active basic使う場合は
負荷かけないとオモロナイ...

110 :108:02/01/08 22:43
スペースつまった
110 DATA "   ■  ","■■■■■ ","  ■■  "," ■ ■  ","■   ■  "
120 DATA "■■■■■ ","    ■ "," ■ ■  ","  ■   ","  ■   "
130 DATA "■■■■■ ","  ■   ","  ■   ","  ■   ","■■■■■ "
140 DATA "■■■■■ ","  ■   ","■■■■■ ","  ■   ","  ■■■  "
150 DATA "  ■   ","■■■■■ ","  ■   ","  ■   "," ■    "
160 DATA "      ","      ","■■■■■ ","      ","      "

50行目のCは反転の画面消去のやつ。170行目のはカーソル制御のやつ

111 :105 >>ActiveBasic:02/01/08 22:57
音源つけて動かしてください。ちと修正しました。
何回も似たようなプログラム書いてスマソ。
10 CLS
20 FOR I=1 TO 25
30 PRINT "オ";:PLAY "O3C16":PRINT "マエ";:PLAY "C8":PRINT "モ";:PLAY "C16":PRINT "ナー ";:PLAY "C4"
40 PRINT "オ";:PLAY "E16":PRINT "マエ";:PLAY "E8":PRINT "モ";:PLAY "E16":PRINT "ナー ";:PLAY "E4"
50 PRINT "オ";:PLAY "G16":PRINT "マエ";:PLAY "G8":PRINT "モ";:PLAY "G16":PRINT "ナー ";:PLAY "G4"
60 PRINT "オ";:PLAY "O4C16":PRINT "マエ";:PLAY "C8":PRINT "モ";:PLAY "C16":PRINT "ナー":PLAY "C4"
70 NEXT I
80 END

112 :&heart;:02/01/08 23:19
そういえば、CHR$なんてのもあったなぁ。
スクロールはこいつで指定すればいいと思われ。

113 :&hearts:02/01/12 14:15
MS-BASICにしようや

114 :大学生MSXユーザ:02/01/13 01:29
今回はさらに原点に戻ってみました。

動作環境:ほぼ全てのBASIC

1 LET A$ = "OMAEMONA- "
2 FOR I = 1 TO 100
3 PRINT A$;
4 NEXT I
5 END

115 :ナイコンさん:02/01/15 18:27
あたらしいお題ほしい

116 :ナイコンさん:02/01/15 21:12
10 SAVE "オマエモナー"
20 FOR A=1 TO 100:PRINT "オマエモナー":NEXT A
30 KILL "オマエモナー"
40 CLS
50 NEW

117 :ナイコンさん:02/01/15 21:16
10 FILES
20 INPUT"ロードシタイ ファイルメイ ";A$
30 KILL A$
40 PRINT "ファイルガ ミツカリマセン"

118 :ナイコンさん:02/01/16 00:34
1さん、あたらしいお題を発表してヨ。

119 :大学生MSXユーザ:02/01/16 01:00
>>1さんは今年に入ってから書きこみ無いみたいだけど
・・・俺がお題出しても良い?>all

120 :ナイコンさん:02/01/16 01:05
次のお題の前に大賞を決めてはおかぬか。

121 :1=JOY ◆chesX68k :02/01/16 07:50
それではエントリーを締め切って選考に入りたいと思います。発表はしばらく待て。
選考は勝手ながら独断でさせてもらうっす。(仕切り厨でスマソ)
次はちょっとテクニカルなお題を考えてるんで、期待してて。

122 :ナイコンさん:02/01/16 10:18
>>1
またBASICでよろしく。

123 :ナイコンさん:02/01/16 14:30
テクニカルなお題もいいけど
くっだらないゲームもきぼーん

124 :ナイコンさん:02/01/16 19:45
>>123
テクニカルなお題をくだらないゲームにするのが腕の見せ所。
しかしテクニカルなお題は俺の脳内BASICインタプリタが処理できないかも(w

125 :ナイコンさん:02/01/17 00:44
審査の間、ワイデスのダンスをお楽しみください

100 WIDTH 40,25:CLS
110 X=18
120 RESTORE
130 READ A
140 IF A=0 THEN 120
150 IF A=4 THEN GOSUB 200
160 IF A=6 THEN GOSUB 300
170 FOR I=0 TO 500:NEXT
180 GOTO 130
200 X=X-1
210 LOCATE X,10:PRINT " \●  ";
220 LOCATE X,11:PRINT "  ■> ";
230 LOCATE X,12:PRINT " < \ ";
240 RETURN
300 X=X+1
310 LOCATE X,10:PRINT "   ●/ ";
320 LOCATE X,11:PRINT " <■  ";
330 LOCATE X,12:PRINT " / > ";
340 RETURN
1000 DATA 4,6,4,6,4,4,4,4,6,6,6,6,0

126 :大学生MSXユーザ:02/01/17 03:55
>>125
MSXに移植してみました。
一部簡単には表現不可能な所があったので独自の修正を施しています。
TurboRの高速モード対応(藁

100 SCREEN 0:WIDTH 40:CLS
110 X=18
120 RESTORE
130 READ A
140 IF A=0 THEN 120
150 IF A=4 THEN GOSUB 200
160 IF A=6 THEN GOSUB 300
170 TIME=0:FOR I=0 TO 10:I=TIME:NEXT
180 GOTO 130
200 X=X-1
210 LOCATE X,10:PRINT " ┐●  ";
220 LOCATE X,11:PRINT "  ロ> ";
230 LOCATE X,12:PRINT " < └ ";
240 RETURN
300 X=X+1
310 LOCATE X,10:PRINT "   ●┌ ";
320 LOCATE X,11:PRINT " <ロ  ";
330 LOCATE X,12:PRINT " ┘ > ";
340 RETURN
1000 DATA 4,6,4,6,4,4,4,4,6,6,6,6,0

127 :JOY ◆chesX68k :02/01/17 21:56
お待たせしました。
第1回昔のPC板杯プログラムコンテストの発表です。
実行可能な物は全て実行してみて、実行できないのは脳内トレースして、
プログラムのアルゴリズムも吟味したうえで決めてみました。


大賞:ナイコンさん >>25
http://pc.2ch.net/test/read.cgi/i4004/1008847300/25
発表直後はスレの住人を震撼させた、まさに衝撃の作品。
誰もが予想だにしなかった方法で課題を実現させている。逆転的発想が大賞
受賞の決め手であり、受賞に関して疑いの余地は無いだろう。
「これをやられちゃったら、このあと何も出せないよ!」という声も・・・・・・。
ほぼ全機種対応という脅威的な汎用性も持っている。
素晴らしい。感動した。


次点:ナイコンさん >>88-89
http://pc.2ch.net/test/read.cgi/i4004/1008847300/88-89
ゲーム化してエントリーされた作品はいくつかあったが、課題のルールを
守ったうえで、見た目にも分かりやすく楽しかった作品がこれ。
100回表示させるのを前提に考えられた画面レイアウトも良い感じ。
「大金もち」「大びんぼう」という言葉のセンスも、当時を思い出させる。
一発系の>>25が無ければ、間違いなく大賞になっていただろう。惜しい。


次点:ナイコンさん >>77
http://pc.2ch.net/test/read.cgi/i4004/1008847300/77
人工無能という崇高な題材に挑戦した作品。
見事に突っ込みだけでスレッドを1本dat行きにさせてしまっている。
惜しむらくは、「オマエモナー」がスレの前半で100回表示しきって
してしまうことと、突っ込み言葉のバリエーション不足。
スレ全体にまんべんなく散りばめられていれば、なお良かったと思われ。


特別賞:大学生MSXユーザさん >>3,>>23
スレ立ち上げ当初からエントリー受け付けギリギリまで作品を提供し続け、
このコンテストを盛り上げた功績は大きい。特別賞を進呈したい。
ハンドル通り、一貫してMSXのプログラムにこだわる職人気質。
色々なアプローチで正統派&技術派な作品を提供してくれた。
現役の(?)大学生でMSXを使っているというのもポイント高し。


(総評)
当時、覚えたてのBASICで組んだ「くだらね〜〜ヨ!」的なノリの
プログラムコンテストをやってみたいと思ったのが始まりなんだが、
みんな付き合って遊んでくれてありがとさん。

今でこそ職業プログラマやってるが、ルーツはこれだろ!みたいな、
そういうのは忘れずにいたいもんだな・・・・・と改めて思たよ。

もっと色々な機種のBASICが見れるかと思ったけど、予想以上に
N系が多かったな。ぴゅう太の日本語ベーシックは出てくるだろ!?と
思っていたんだが・・・・・・。お題が悪かったか?。正直スマン。
ワイデスネタも出ると踏んでたが・・・・。あ、最後に出たね。

やはり、昔のPC板らしくBASIC限定のほうが楽しいな。
機種毎に方言があるところが、また楽しい。
次回もまたヨロシク!!



128 :JOY ◆chesX68k :02/01/17 21:57
ということで、大賞を決めてみた。予想通りだったかな??。

新しいお題のネタはあったんだが、>>119で 大学生MSXユーザさんが
お題を出したいようだったので、彼に一任することにしたいけど、どう?。
ま、特別賞の御褒美って事で。特に反論がなければ、そうしよう。

>>123で「くっだらないゲーム」という希望もあるので、そのことも考慮して
決めちゃってください>大学生MSXユーザさん

この後は、第2回として新スレを立てるかどうか?を このままこのスレで
議論しつつ、しばらくは第1回の感想などでマターリしようよ。
第2回を新スレにするなら、このスレは sage進行専用の方向で。


>>119
> 1さんは今年に入ってから書きこみ無いみたいだけど
最近は P/ECEのほうに凝っててなー。そっちのコンテストに向けてプログラムに
萌えているよ・・・・って、このスレとは直接関係無いから sageとく。



129 :俺も参加する:02/01/18 00:07
10 NEW



130 :大学生MSXユーザ ◆Ym1dK0rg :02/01/18 00:36
ども、特別賞頂いた大学生MSXユーザです。

>>1=JOY ◆chesX68kさん了解しました。
さっそく第2回のお題と>>1用の文章考えてみたんで評価頼みます。>all

===ここから
毎年恒例となった 第2回昔のPC板杯プログラムコンテストを開催するヨ!
かつてやった(であろう)クダラネー!!プログラムや クダラネー!!テクニックを
再びここで披露して下さい。

目的:2ちゃんねる系キャラクター(モナー、ギコ猫、etc...)
   を使ったくだらないミニゲームを作る。

使用機種:不問

使用言語:BASIC限定(各機種の方言の使用は可)
     また、コードがBASICのみで書かれているならばマシン語の使用も可とします。

条件:プログラムコードが長くならないように注意。
   (省略されました・・全てを読むにはここを押してください)が
   出てしまったら、そのエントリーは無効。

評価:今度は投票で決めたいと思います。

投票方法:(゚∀゚)イイ!と思ったプログラムのスレ番号をxxxとして、
     名前欄には適当なトリップを付けて、本文には
     1行目に「投票xxx」(xxxは半角数字で)と書き、
     2行目以降には感想を書いて(←これは無くても良い)
     レスして下さい。このフォーマットから外れたレスは無効票とします。
     なお、一人2票まで投票可能とします。

     前スレ同様、綺麗なソースやアルゴリズムだけではなく、
     実行したときの芸術性などを考慮した上で評価してください。

注意:半角空白は連続して書くと1つに纏められて見えてしまう為、
   &nbsp;又は全角空白に置き換えてレスして下さい。
   また、機種依存文字は出来るだけ似た字に置き換えて書いた上で注釈を入れて下さい。

エントリーする人は、動作機種を(ものによっては何BASICかも)明記して下さい。

エントリー終了と投票開始の時間はこの>>1の投稿日から丁度30日経った”瞬間”です。

エントリーに対するレスなんかは随時大いにしちゃってOK!もりageて行こう!
ビクーリするようなヤツ期待してます!
===ここまで


131 :ナイコンさん:02/01/18 00:42
>>130
「ルール詳細は>>2参照」ってのをきぼーん

132 :ナイコンさん:02/01/18 02:12
>>128
とりあえず新スレは見合わせた方がいいと思う。まだ100ちょっとしか使ってないわけだし。
ただ、そうなると現在のレギュレーションがわかりにくくなるという難点があるので、
定期的にレギュレーションにリンクを貼る等の行為が必要となるかも。

>>130
モナーやギコ猫のAAを作れない機種も出て来るかと思うので、
単純に「くだらないミニゲームを作る」でよいかも。

使用言語の「コードがBASICのみで書かれているならばマシン語の使用も可とします」は
ちょっとニヤリとさせられた。


133 :ナイコンさん:02/01/18 02:19
もうちょっと目的を限定しないとコンテストになんないよ

134 :ナイコンさん:02/01/18 02:27
短いプログラムしか載せられないので、ワンキーゲームとかどう?


135 :名無しさん:02/01/18 03:14
8bit機だと表示できる文字種が少なくてAAは厳しいよぉ。
そのへん何とかならんかね。

136 :大学生MSXユーザ ◆Ym1dK0rg :02/01/18 03:35
>>131さん
確かにそのほうが良いと思います。

>>132,>>135さん
確かに>>125を移植したときも必要な文字無くて困ったんで。
MSXの様に文字の形を再定義出来るマシンは良いとして
MZ-700みたいに固定されてるマシンもあるし。
2ちゃんねる系キャラ限定は解除ですかね。

>>134さん
それ(゚∀゚)イイ!です。

で、以上を踏まえて考えてみた修正案(>>130からの差分)
・文全体を>>2に移動。
・目的をくだらないワンキーミニゲームに偏光^H^H変更。
・注意:の2行目先頭に誤植?「又は」→「&nbsp;を半角で、又は」
・(新スレ立てる場合)このスレへのリンクを追加。

問題点
・本当に新スレを立てるか?
・スレの管理
(俺今4年生なんです。暫くしたら卒論が・・・)

あと、あんましこのスレと関係無いんだけど(w
各機種固有の命令の使い方間違ってるのとか合ったりしたんで、
「昔のPCのBASICの文法を勝手に教えるスレ」
とか立てたら人来ると思います?

というわけで継続して意見レスキボーン。


137 :ナイコンさん:02/01/19 11:37
誰か>>25をぴゅう太に移植してくれ。

>>130、136
投票にこだわる必要もないと思うなあ。
MSXユーザ氏の一存で決めても文句でないと思うし。
少なくとも投票にトリップは不要でしょう。

BASICの文法を勝手に教えるスレは需要はあるとおもう。
BASICの移植に関する指針とかも話題に加えていいかも。
もし立てたらこのスレからのリンクは必須だね。
個人的には欲しい。情報提供はできないけど(w


138 :ナイコンさん:02/01/20 02:53
目指せ「昔のPC板のベーマガ」だな。
乗り遅れたが、一応書いておく

PC-6001 N60-BASIC
10 ? "オマエモナー"
20 C=C+1:IF C=100 THEN EXEC 0
30 GOTO 10


139 :大学生MSXユーザ ◆Ym1dK0rg :02/01/28 02:53
スレ放置してしまってすいませんでした。
今週は風邪と期末テストでダウンしててまともにネット繋げてませんでした。
次スレの文案を作ってみました。
それと、次スレの管理は>>1= JOY ◆chesX68kさんに頼みたいんですけど良いですか?

REM あと3周間程で卒論の締め切りという罠 =ロo_

次スレ>>1
=======================================
毎年恒例となった 第2回昔のPC板杯プログラムコンテストを開催するヨ!
かつてやった(であろう)クダラネー!!プログラムや クダラネー!!テクニックを
再びここで披露して下さい。

詳しくは>>2で。

前スレ http://pc.2ch.net/test/read.cgi/i4004/1008847300/
※)前スレはこのスレに関連した雑談用途に使用してください。


次スレ>>2
=======================================
目的:くだらないワンキーミニゲームを作る。

使用機種:不問

使用言語:BASIC限定(各機種の方言の使用は可)
     また、コードがBASICのみで書かれているならばマシン語の使用も可とします。

条件:プログラムコードが長くならないように注意。
   (省略されました・・全てを読むにはここを押してください)が
   出てしまったら、そのエントリーは無効。

評価:前スレとは違って今度は投票で決めたいと思います。

投票方法:(゚∀゚)イイ!と思ったプログラムのスレ番号をxxxとyyyとして、本文に
     1行目に「投票xxx+yyy」(xxx+yyyは半角数字で)と書き(1票のみの場合は「投票xxx」と書く)、
     2行目以降には感想を書いて(←これは無くても良い)
     レスして下さい。このフォーマットから外れたレスは無効票とします。
     なお、上記の通り一人2票まで投票可能とします。

     投票締め切りは900まで又は最初の作品が出てから丁度30日までとします。

     前スレ同様、綺麗なソースやアルゴリズムだけではなく、
     実行したときの芸術性などを考慮した上で評価してください。

注意:半角空白は連続して書くと1つに纏められて見えてしまう為、
   &nbsp;を半角にしたもの、又は全角空白に置き換えてレスして下さい。
   また、機種依存の特殊文字は出来るだけ似た字に置き換えて書いた上で注釈を入れて下さい。

エントリーする人は、動作機種を(ものによっては何BASICかも)明記して下さい。

エントリー終了と投票開始の時間はこの>>1の投稿日から丁度30日経った”瞬間”です。

エントリーに対するレスなんかは随時大いにしちゃってOK!もりageて行こう!
ビクーリするようなヤツ期待してます!


140 :大学生MSXユーザ@学校:02/01/28 11:13
あぅ。age忘れ。

141 :ナイコンさん:02/01/28 13:48
このスレ最高。
っつーか、漏れも未だにポケコン使って子供の遊戯王カード用計算プログラムとかBASICで作ってるし。
次スレはエントリーすんぞ〜。

142 :ナイコンさん:02/01/28 16:08
みんなでコレ使ってプログラム持ち寄らねえ?
http://www.sagami.ne.jp/tadaka/99Basic/


143 :ナイコンさん:02/01/28 16:35
漏れマカーなんだけど、BASICが走るようなエミュしらん?
88とか98のやつ。
次回は参加してーよー。

144 :ナイコンさん:02/01/29 19:02
>>142
ついにフリーなのね。かなっすぃ〰

145 :ナイコンさん:02/01/29 19:09
檻はn88のままだ

146 :大学生MSXユーザ ◆Ym1dK0rg :02/01/30 03:28
特に意見が無いようなら今度の土曜日にでも新スレ立てときます。
意見等はそれまでにお願いします>ALL

>143
一応こんなの見つけました。(動くかどうかは判らない(MAC持ってないんで))
ttp://www.mode.co.jp/down/d-futurebasic.html


147 :JOY ◆chesX68k :02/01/30 09:59
久々に来てみたら、このスレこんなに下がってるよ。
しかもまだ第2回が始まってないし・・・・・。大学生MSXユーザクン頑張れ!

ちょっと意見させてもらうと、投票とかあまりこだわらんでも良いと思うよ。
そんときのノリやパッと浮かんだアイディアを思いつきだけで組んでいた
あの頃のプログラムスタイルを懐かしむスレにしたい。個人的にはね。
まさに「くだらねーよ!」って笑えるようなやつ。
肩の力抜いてお気軽プログラム!なのが 当時のBASICの良いところだしさ。

投票形式にするなら、レギュレーションを決めて、エントリが少なくなってきたら
そろそろ締め切って投票にしましょう!てな感じかな。そこは臨機応変に。
まだまだエントリーがあるうちに投票してもね。
後でどんな(゚∀゚)スゲー!の出るか分からんしさ。

いろんな機種の方言を知っている解説者みたいな人がいたら良いかもね。
Dr.Dみたいな人募集!といってみるテスト。

>>139
2chはあまり覗けないけど、進行役ならしても良いよ。
つーか俺立てたスレだった。立て逃げはいかんよね、立て逃げは。鬱。

そんな感じで。いちおう ageときます。


148 :ナイコンさん:02/01/30 10:02
>>143
Mac用88Emuはあったと思うが。


149 :ナイコンさん:02/01/30 11:13
>>143
www.hi-ho.ne.jp/hideaki-i/n_on_mac/n-index.html


150 :ナイコンさん:02/01/30 23:26
>>142
99ベーシックって、コピペが使えなくない?

151 :ナイコンさん:02/01/31 00:57
ここ見てたら昔を思い出した(泣
おれも参加したくなって9801MのマニュアルもらってきたYo

第2回のスレが立ったらここはベーマガの下の部分(over flowだっけ)
みたいにするってのはどうよ

>大学生MSXユーザさん
体に気をつけて。無理すんなよ。

152 :ナイコンさん:02/01/31 01:16
>150
コピペは無理かもしれないけど。

99 BASICのヘルプファイル見たら
text形式のファイル読めるみたい


153 :ナイコンさん:02/01/31 08:11
>>152
THX!ホントだ!
セーブデータをメモ帳で開くと化けまくりというのはご愛嬌かな?(w


154 :152:02/01/31 18:03
>153
saveは独自形式だからね。
オプションAをつけるとtext形式でsaveできるようです
詳しくはヘルプファイルのsaveの項目参照してね




155 :150=153:02/01/31 18:45
>>153
度々スマソ&THXです。
HELP見直してやってみたら確かに「SAVE "〜",A」で「〜.TXT」と保存されました!
関係無いけど、ついつい「csave"〜」と打ってしまう…(w


156 :大学生MSXユーザ ◆Ym1dK0rg :02/01/31 23:55
JOY ◆chesX68kさん。新スレの進行役頼みます。m(_ _)m

俺は人のコード評価出来るほどの奴じゃないんで投票方式を考えた
んですけど、逃げはいけませんね。はぅ。

やっぱり>1さんの案に近い文に直してみて金曜の午後にでも
このスレに書いときます。

新スレは>146にも書いた通り土曜に立てます。


>151
あー既に先週風邪でダウンしたんで
しばらくは大丈夫だと思います。(w


157 :ナイコンさん:02/02/01 00:54
http://www.vector.co.jp/soft/win95/prog/se063951.html

ここに通常の形式で保存したファイルをテキストに変換できるツールがあります。実機がなくても大丈夫ですね。

158 :ナイコンさん:02/02/01 07:32
レスが200も満たないうちに新スレなど言われても困るので
次はちゃんと使いまわせそうなスレタイトルにしてください。


159 :143:02/02/01 11:46
>>149
情報サンクス!
早速行ってみたんだけど・・・わし実機持ってないんすよ。(T_T)
ROMイメージが手に入らんです。

160 :大学生MSXユーザ ◆Ym1dK0rg :02/02/01 16:46
こんな感じでどうでしょう?

せっかく立ててあるこのスレを使いきらないともったいないんで
ここは第2回以降のコンテストスレ関連の雑談に使うと良いと思います。

次スレ名称:第2回昔のPC板杯プログラムコンテスト会場

次スレ>>1
=======================================
恒例となった 第2回昔のPC板杯プログラムコンテストを開催するヨ!
かつてやった(であろう)クダラネー!!プログラムや クダラネー!!テクニックを
再びここで披露して下さい。

詳しくは>>2で。

前スレ http://pc.2ch.net/test/read.cgi/i4004/1008847300/
※)前スレは昔のPC板杯プログラムコンテストに関連した雑談用途で使用することを推奨します。


次スレ>>2
=======================================
目的:くだらないワンキーミニゲームを作る。

使用機種:不問

使用言語:BASIC限定(各機種の方言の使用は可)
     また、コードがBASICのみで書かれているならばマシン語の使用も可とします。

条件:プログラムコードが長くならないように注意。
   (省略されました・・全てを読むにはここを押してください)が
   出てしまったら、そのエントリーは無効。

評価:綺麗なソースやアルゴリズムだけではなく、実行したときの
   芸術性、くだらなさ、ゲームの面白さ、etc.なども評価の対象とします。

注意:半角空白は連続して書くと1つに纏められて見えてしまう為、
   &nbsp;を半角にしたもの、又は全角空白に置き換えてレスして下さい。
   また、機種依存の特殊文字は出来るだけ似た字に置き換えて書いた上で注釈を入れて下さい。

エントリーする人は、動作機種を(ものによっては何BASICかも)明記して下さい。

エントリーに対するレスなんかは随時大いにしちゃってOK!もりageて行こう!
ビクーリするようなヤツ期待してます!


161 :ナイコンさん:02/02/01 19:36
BASICじゃないと不可なんですかー。ぷりぷり。


162 :元ぴゅう太ユーザー:02/02/01 20:11
乗り遅れ気味だけど、ぴゅう太G-BASICで。
実機が行方不明なんでうろ覚えだけど、多分こんな感じ。

10 マワレ30 A=1カラ600カンカク6
20 カケ A, "オマエモナー"
30 トジル
40 オワリ

で、メニューから「ジツコウ」と打つと青地に白で表示。

ちなみにぴゅう太の画面は横32セル×縦24セルで、
位置指定は左上端1〜右下端768の範囲。

>>137
G-BASICはプログラム中でリストを出力する命令を実行できないので、移植不可。

163 :元ぴゅう太ユーザー:02/02/01 20:18
しまった。
>>162
10 マワレ30 A=1カラ601カンカク6
じゃないと1つ足りないような。逝ってきます…

164 :大学生MSXユーザ ◆Ym1dK0rg :02/02/02 02:04
次スレ立てました。

第2回昔のPC板杯プログラムコンテスト会場
http://pc.2ch.net/test/read.cgi/i4004/1012582935/


165 :ナイコンさん:02/02/02 10:54
誰かMSXのRND書式教えて〜。RANDOMIZEの書式もよろしく。

166 :誰か:02/02/02 11:54
RND(X)
Xの条件:数値型定数, 変数, 配列変数, 式。
返される値: 数値型。

0<X の時:常に一定の系列の乱数を発生する。
X=0 の時:1つ前に発生したのと同じ値を返す。
X<0 の時:Xの値に対応する発生系列を作り、
     それ以降の RND関数はその系列で乱数を発生する。
-----------
MSXにあるのはRNDだけで、RNDが RANDOMIZEも兼ねてるみたいですね。

167 :ナイコンさん:02/02/02 15:54
>>166
さんくす!

・・・むむむ。でもRANDOMIZE効かないなぁ。

10 CLS:CLEAR
20 FOR I=1 TO 20
30 A=10*(RND(10))
40 PRINT INT(A)
50 NEXT I

これでrunしても、毎回同じ乱数しか出ないっす・・・。(T_T)
分かる人、誰か教えて下さい。

168 :ナイコンさん:02/02/02 16:03
>>167
MSXは使ってないからわからないけど>>166を見ると、
始めにRND(-TIME)とかやっておけばいいんじゃないの?


169 :ナイコンさん:02/02/02 16:31
>>167
30 A=INT(RND*10)

だったらどうよ?
違うかもしれんが。


170 :ナイコンさん:02/02/02 16:36
>>169
それを言うなら、
30 A=INT(RND(1)*10)


171 :169:02/02/02 16:50
>>170
おっしゃる通りっす。


172 :ナイコンさん:02/02/02 17:17
色々さんくす!>ALL
まず、>>170さんありがとうございます。行がスッキリしました。
で、
30 A=INT(RND(1)*10)
で綺麗にいったんですが、結局RANDMIZEできません。

>>168さん
これって例えば
15 RND(-TIME)
とかじゃないんですよね(Syntax error出た)。
「-TIME」って時間かなんかの変数でしょうか?

う〜、今までポケコンでは
RANDOMIZE:A=RND 10
↑コレで済んでたもんで・・・。

173 :ナイコンさん:02/02/02 17:28
10 CLS
20 PRINT "ムカシノPC@2chケイジバン
30 PRINT "http://pc.2ch.net/i4004/
40 END

174 :ナイコンさん:02/02/02 17:36
10 ’RUNだMy図、がないと将来踊れないよ。他力踊り希望の人?
20 ’それはやめたほうがいいよ。

175 :170:02/02/02 17:43
>>172
おれはMSXユーザでないから MSX=BASICは詳しくは分からんが、
要は起動するたびに違った数値を引っ張ってくれば良いわけだからさ.....
15 RND(VAL(RIGHT$(TIME$,2)))
なんかではどうだろ?

RANDOMIZE(VAL(RIGHT$(TIME$,2)))
てのが、N-80/88では定石でした。


176 :大学生MSXユーザ ◆Ym1dK0rg :02/02/02 17:44
>172

15 ZZ= RND(-TIME)
と適当な変数への代入にすればOK。

TIMEは1/60秒毎にカウントアップされる変数だよ。
こいつは自分で値をセットすることも出来るから簡単な時間計測に使えたりする。

例)30行の計算時間を計る。

10 TIME= 0
20 FOR I=1TO100
30 Z=ATN(1)^ATN(1)
40 NEXT I
50 T= TIME/60/100
60 PRINT "ヤク"; T; "秒"


177 :ナイコンさん:02/02/02 19:00
1/60毎にカウントアップならば、
50 T = TIME/60
なんじゃねーの?と言ってみるテスト。


178 :大学生MSXユーザ ◆Ym1dK0rg :02/02/02 20:48
>177

>176の例では30行を100回実行して1回あたりの時間を
計算してるのでこれでOKです。

30行を1回しか実行しない場合、1/60の精度までしか出ないけど、
100回やって時間を100で割れば1/6000の精度で測定できます。

#実際にはFOR文で消費される時間を差し引いて計算しないと
#いけないんだけど、その処理は例って事で省略してあります。


179 :ナイコンさん:02/02/03 01:43
言語を、統一した方がいいと思うよ。もしくは、機種依存する命令は使わないとか。
みんなのソースをためせる方が、盛り上がると思うし。

180 :172:02/02/03 10:48
おお〜、なんかレベルの高いレスありがとうございます!
今仕事中ですので、帰ってから色々試してみたいと思います。

181 :ナイコンさん:02/02/03 15:39
>>180=>>172
つーか、第2回のスレ立ってるんだし、こっちはsage進行したほうが良いぞ。


182 :ナイコンさん:02/02/04 20:48
このスレ(主に第2回スレ)がスレの杜で紹介されてるけど
スレの杜で紹介されるってステータスなの?
ちょっとビクーリしたYo.

183 :ナイコンさん:02/02/05 14:49
>182
けっこうステータスではないかと。
実は推薦したの俺なんだけど、あーゆー形で取り上げられるとは思わなかった。

184 :ナイコンさん:02/02/06 00:25
>52
99回でループから抜けてしまいませんか?

185 :ナイコンさん:02/02/27 18:36
遊び方は、実行後にシフトキーを連打して下さい。最後に表示される。
タイムの多い人が勝ちです。他のキーでも出来るかもしれません。

100 REM PC-8801/mk2テイドマデ
110 DEF USR=28342
120 CONSOLE ,,1,1:WIDTH 80,25:SCREEN 0,1
130 SCREEN ,1:CLS USR(0)
140 TIME$="00:00:00"
150 PAINT(2,100),2
160 PRINT TIME$
170 END


186 :ナイコンさん:02/02/28 06:45
久しぶりに来たけどまだ続いてたんだ。
良かった…。

187 :ナイコンさん:02/03/09 20:45
第2回へ

188 :ナイコンさん:02/03/23 14:49
こっそりsage

189 :ナイコンさん:02/06/21 00:38
100 goto 100

190 :ナイコンさん:02/06/21 00:54
言語を統一した方が盛り上がると思うな。

191 :ナイコンさん:02/06/21 05:52
>>190
お前、この板初心者だろ?


192 :ナイコンさん:02/06/21 07:29
>>191
1を読めばわかるけどBASIC限定です

193 :ナイコンさん:02/06/21 12:41
>>191
お前、BASICを知らない初心者だろ?

194 :ナイコンさん:02/06/21 14:07
delete 190
OK
list 191-
191 名前:ナイコンさん :02/06/21 05:52
>>190
お前、この板初心者だろ?



192 名前:ナイコンさん :02/06/21 07:29
>>191
1を読めばわかるけどBASIC限定です


193 名前:ナイコンさん :02/06/21 12:41
>>191
お前、BASICを知らない初心者だろ?

OK


195 :ナイコンさん:02/06/22 19:32
delete 194
OK

196 :GOTO  1 ':02/06/29 16:30


197 :END:02/07/17 13:00


198 :age:02/09/05 01:54
10 REM ホシュsage
20 END

199 :ナイコンさん:02/09/19 11:59
ActiveBASICはexitで終了だが、
99BASICは終了時はsystemって打つのね。
昔を思い出して笑ったよ〜

200 :ナイコンさん:02/09/20 01:04
LEFT$("00"+ HEX$(A), 2)

201 :ナイコンさん:02/09/29 13:45

1000 CLS 3 : A = 400 : B = 8000 : C = 100
1100 FOR Z = 1 TO C
1200 FOR X = 1 TO 7
1300 COLOR X : LOCATE 15,15 : PRINT "キタ (゚∀゚) !!!!!"
1400 FOR Y = 1 TO A : NEXT Y
1500 COLOR X : LOCATE 15,15 : PRINT "キタ ━(゚∀゚)━ !!!!!"
1600 FOR Y = 1 TO A : NEXT Y
1700 COLOR X : LOCATE 15,15 : PRINT "キタ ━━(゚∀゚)━━ !!!!!"
1800 FOR Y = 1 TO A : NEXT Y
1900 COLOR X : LOCATE 15,15 : PRINT "キタ ━━━(゚∀゚)━━━ !!!!!"
2000 FOR Y = 1 TO A : NEXT Y
2100 COLOR X : LOCATE 15,15 : PRINT "キタ ━━━━(゚∀゚)━━━━ !!!!!"
2200 FOR Y = 1 TO A : NEXT Y
2300 COLOR X : LOCATE 15,15 : PRINT "キタ━━━━━━(゚∀゚)━━━━━━ !!!!!"
2400 BEEP
2500 FOR Y = 1 TO B : NEXT Y
2600 NEXT X
2700 NEXT Z
2800 END

202 :ナイコンさん:02/09/29 13:49
1000 CLS 3 : A = 400 : B = 8000 : C = 100
1100 FOR Z = 1 TO C
1200 FOR X = 1 TO 7
1300 COLOR X : LOCATE 15,15 : PRINT "キタ (゚∀゚) !!!!!"
1400 FOR Y = 1 TO A : NEXT Y
1500 COLOR X : LOCATE 15,15 : PRINT "キタ ━(゚∀゚)━ !!!!!"
1600 FOR Y = 1 TO A : NEXT Y
1700 COLOR X : LOCATE 15,15 : PRINT "キタ ━━(゚∀゚)━━ !!!!!"
1800 FOR Y = 1 TO A : NEXT Y
1900 COLOR X : LOCATE 15,15 : PRINT "キタ ━━━(゚∀゚)━━━ !!!!!"
2000 FOR Y = 1 TO A : NEXT Y
2100 COLOR X : LOCATE 15,15 : PRINT "キタ ━━━━(゚∀゚)━━━━ !!!!!"
2200 FOR Y = 1 TO A : NEXT Y
2300 COLOR X : LOCATE 15,15 : PRINT "キタ━━━━━━(゚∀゚)━━━━━━ !!!!!"
2400 BEEP
2500 FOR Y = 1 TO B : NEXT Y
2600 NEXT X
2700 NEXT Z
2800 END

203 :ナイコンさん:02/09/29 13:52
 ↑
??? 上の二つ、PRINT文の中のspaceが消えてる・・・  
しかも結局二重投稿だし・・・   鬱



Syntax error
ok



204 :ナイコンさん:02/09/29 14:32
>203
連続の半角空白は1つに圧縮されます。
で、半角で「&nbsp;」と書くと圧縮されない半角空白に置き換わります。

205 :ナイコンさん:02/09/29 16:21
>>204
ひとつおりこうになりますた ありがとうございますた m(_ _)m

206 :ナイコンさん:02/12/03 04:08
なるほど

207 :ナイコンさん:02/12/24 19:34
0 go to 0

208 :WIDTH :02/12/24 22:06

●/ < RANDOMIZEニ タヨラナイ、ランスウノ カエカタ。
PRINT"HIT SPACE KEY!":WHILE INKEY$<>" ":A=RND(1):WEND

●/ < ソノ オウヨウレイ。
http://pc.2ch.net/test/read.cgi/i4004/1037113354/202

209 :WIDTH 40:02/12/24 22:09
三(#゚Д)つΣ●/ < >>208ハント゛ルメイヲ ウチソコネマスタ!

210 :山崎渉:03/01/13 21:51
(^^)

211 :山崎渉:03/03/13 17:31
(^^)

212 :山崎渉:03/04/17 12:22
(^^)

213 :山崎渉:03/04/20 06:02
   ∧_∧
  (  ^^ )< ぬるぽ(^^)

214 :山崎渉:03/05/28 17:12
     ∧_∧
ピュ.ー (  ^^ ) <これからも僕を応援して下さいね(^^)。
  =〔~∪ ̄ ̄〕
  = ◎――◎                      山崎渉

215 :山崎 渉:03/07/15 11:10

 __∧_∧_
 |(  ^^ )| <寝るぽ(^^)
 |\⌒⌒⌒\
 \ |⌒⌒⌒~|         山崎渉
   ~ ̄ ̄ ̄ ̄

216 :なまえをいれてください:03/07/22 13:00
ハッキリ言ってアメリカなどの多民族国家では黒人の方がアジア人よりもずっと立場は上だよ。
貧弱で弱弱しく、アグレッシブさに欠け、醜いアジア人は黒人のストレス解消のいい的。
黒人は有名スポーツ選手、ミュージシャンを多数輩出してるし、アジア人はかなり彼らに見下されている。
(黒人は白人には頭があがらないため日系料理天などの日本人店員相手に威張り散らしてストレス解消する。
また、日本女はすぐヤラせてくれる肉便器としてとおっている。
「○ドルでどうだ?(俺を買え)」と逆売春を持ちかける黒人男性も多い。)
彼らの見ていないところでこそこそ陰口しか叩けない日本人は滑稽。

217 :ぼるじょあ ◆ySd1dMH5Gk :03/08/02 04:59
     ∧_∧  ∧_∧
ピュ.ー (  ・3・) (  ^^ ) <これからも僕たちを応援して下さいね(^^)。
  =〔~∪ ̄ ̄ ̄∪ ̄ ̄〕
  = ◎――――――◎                      山崎渉&ぼるじょあ

218 :ナイコンさん:04/02/24 16:00
α

219 :ナイコンさん:04/02/25 19:18
β

220 :ナイコンさん:04/05/01 21:04
γ

221 :ナイコンさん:04/05/02 17:05
δ

222 :ナイコンさん:04/05/03 21:21
auto 223,1

223 :ナイコンさん:04/05/07 17:51
シルフィード 1面でやられると
「オンマエモナイヨワークワッカッ ハー!」

224 :ナイコンさん:04/05/07 18:01
208のリンク先が見れないなぁ
RANDOMIZEって毎回同じ結果になるから使えないよね?
それを消すためのプログラムがあるのは知ってたが、資料不足でどうにもできず。
田舎で月1000円の小遣いとかじゃどうにも資料を集めるできんかった厨房の頃。

225 :ナイコンさん:04/05/12 23:07
ビギナーズオールパーパスシンボリックインストラクションコード!
BASIC
Syntax Error
Ok

226 :ナイコンさん:2005/04/17(日) 16:38:42
保守

227 :ナイコンさん:2005/06/04(土) 03:06:52
最下層

228 :ナイコンさん:2005/06/05(日) 01:24:07
最下層って目立つよな。

あげw

73 KB
■ このスレッドは過去ログ倉庫に格納されています

★スマホ版★ 掲示板に戻る 全部 前100 次100 最新50

read.cgi ver 05.04.00 2017/10/04 Walang Kapalit ★
FOX ★ DSO(Dynamic Shared Object)